Production.uWorkOrder Trigger

Information

Name	Production.uWorkOrder
Table Name	Production.WorkOrder
Created	14.10.2005 1:59:58
Modified	14.10.2005 1:59:58
Disabled
For replication
Instead of trigger
Activates on	UPDATE

SQL Script

CREATE TRIGGER [Production].[uWorkOrder] ON [Production].[WorkOrder] 
AFTER UPDATE AS 
BEGIN
    SET NOCOUNT ON;

    BEGIN TRY
        IF UPDATE([ProductID]) OR UPDATE([OrderQty])
        BEGIN
            INSERT INTO [Production].[TransactionHistory](
                [ProductID]
                ,[ReferenceOrderID]
                ,[TransactionType]
                ,[TransactionDate]
                ,[Quantity])
            SELECT 
                inserted.[ProductID]
                ,inserted.[WorkOrderID]
                ,'W'
                ,GETDATE()
                ,inserted.[OrderQty]
            FROM inserted;
        END;

        UPDATE [Production].[WorkOrder]
        SET [Production].[WorkOrder].[ModifiedDate] = GETDATE()
        FROM inserted
        WHERE inserted.[WorkOrderID] = [Production].[WorkOrder].[WorkOrderID];
    END TRY
    BEGIN CATCH
        EXECUTE [dbo].[uspPrintError];

        -- Rollback any active or uncommittable transactions before
        -- inserting information in the ErrorLog
        IF @@TRANCOUNT > 0
        BEGIN
            ROLLBACK TRANSACTION;
        END

        EXECUTE [dbo].[uspLogError];
    END CATCH;
END;